Настройка схемы таблиц
Вся информация в платформе отражается в табличном виде, использующие разные настройки. Схема таблицы - это совокупность текущих настроек таблицы. В системе отображения может быть определено множество экземпляров схем. Существует схема по умолчанию и текущая схема. Текущая схема - это набор настроек таблицы, используемый в данный момент. Схема по умолчанию используется, когда не задано никакой схемы таблицы. Также схема по умолчанию используется для определения набора видимых столбцов и их порядка при нажатии кнопки По умолчанию в диалоге настройки, при этом атрибуты столбцов в текущей схеме не перезаписываются.
Схема по умолчанию может настраиваться для режима настроек журнала, варианта подчиненной таблицы журнала, а также варианта данных плана аналитики.
Для сохранения всех настроек схемы таблиц в системе отображения используется объектный тип ЛКФ_СХЕМА, в полях которого указывается экземпляр схемы с настройками и имя блока для которого создается указанная схема данных. При помощи метода ЗАПИСАТЬ производится связывание имени схемы и типа таблицы, для которой назначается схема.
Так как в платформе существует несколько типов таблиц, то каждый тип таблицы во внутреннем языке представлен константой из набора ЛКФ_ТАБ_... Для определенных типов таблиц в схеме уже определены названия столбцов по умолчанию. Стандартные названия столбцов в таблицах определяются константами из набора ЛКФ_СТОЛБЕЦ_... Удаление стандартных столбцов невозможно, поэтому при удалении встроенных столбцов из схемы таблиц они будут скрыты.
При настройке схемы таблиц стоит учитывать, что при добавлении столбцов, чтобы в их ячейках отображались определенные данные связанные например, со свойством объекта аналитики, то название столбца схемы должно соответствовать названию свойства, данные которого будут отображаться в ячейках этого столбца.
Методы внутреннего языка платформы при помощи логического параметра по_умолчанию позволяют указывать имя какой схемы считывать или устанавливать для режима настроек - имя схемы по умолчанию или имя текущей схемы. По умолчанию считывается/устанавливается имя текущей схемы таблицы. Ниже указаны методы считывания и установки имени схемы для режима настроек отображения.
- ЛКФ_РЕЖИМ_ЖУРНАЛА.СХЕМА
- ЛКФ_РЕЖИМ_ЖУРНАЛА.ЗАП_СХЕМУ
- ЛКФ_ЖУР_ПОДЧ_ВАР.СХЕМА
- ЛКФ_ЖУР_ПОДЧ_ВАР.ЗАП_СХЕМУ
- ЛКФ_АНАЛИТ_РЕЖИМ.СХЕМА_ВАР
- ЛКФ_АНАЛИТ_РЕЖИМ.ЗАП_СХЕМУ_ВАР
В примере ниже демонстрируется создание блока настроек отображения для ветки объекта аналитики "ТОВАРЫ" и редактирования для варианта данных "основной" объекта аналитики схемы таблиц. Перед редактированием схемы таблиц происходит проверка наличия такой схемы таблиц для варианта данных, если для варианта данных нет схемы таблиц, то происходит установка схемы и последующая запись настроек.
ВЫЧИСЛИТЬ
ПЕРЕМ СХЕМА: схема
схема.изм_порядка = ДА
схема.изм_загол = НЕТ
схема.изм_оформл = НЕТ
схема.доб_новых = НЕТ
схема.столбцы = (1: [имя = ЛКФ_СТОЛБЕЦ_КОД,
заголовок = "Код",
фикс = ДА,
показ_имя = ДА,
видимый = ДА,
ширина = 150,
авто_ширина = НЕТ,
поиск = ДА,
сортировка = ДА,
разр_сорт = ДА
],
2: [имя = ЛКФ_СТОЛБЕЦ_НАЗВАНИЕ,
заголовок = "Наименование",
показ_имя = ДА,
видимый = ДА,
ширина = 100,
авто_ширина = ДА,
поиск = НЕТ,
сортировка = НЕТ,
разр_сорт = НЕТ
]
)
ПЕРЕМ ЛКФ_ВЕТКА: ветка_товары
ветка_товары.корень = "ТОВАРЫ"
ветка_товары.УСТ_БЛОК("Блок_2")
ПЕРЕМ ЛКФ_АНАЛИТ_РЕЖИМ: аналит_реж
аналит_реж = [ветка = ветка_товары]
ПЕРЕМ имя_схемы = аналит_реж.СХЕМА_ВАР("" , НЕТ)
ЕСЛИ имя_схемы = "" ТО
имя_схемы = "схема_варианта"
аналит_реж.ЗАП_СХЕМУ_ВАР("", имя_схемы, НЕТ)
КОНЕЦ_ЕСЛИ
ПЕРЕМ ЛКФ_СХЕМА: лкф_схема = [блок = "Блок_2", схема = схема]
лкф_схема.схема = схема
лкф_схема.ЗАПИСАТЬ(ЛКФ_ТАБ_ОБЪЕКТОВ, имя_схемы)
КОНЕЦ